blob: 7b30454e7a756e2e4dc4682033f1618ea99daaaf (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
/* SPDX-License-Identifier: copyleft-next-0.3.1 */
/* Copyright 2023 Kim Kuparinen < kimi.h.kuparinen@gmail.com > */
%option reentrant noyywrap nounput noinput nodefault
%{
#define FROM_LEXER
#include <lyn/parser.h>
#include <lyn/debug.h>
static void update_yylloc(struct parser *parser, YYLTYPE *lloc, const char *text)
{
(void)parser;
lloc->first_line = lloc->last_line;
lloc->first_column = lloc->last_column;
for (size_t i = 0; text[i] != 0; ++i) {
if (text[i] == '\n') {
lloc->last_line++;
/* flex uses 1 based indexing */
lloc->last_column = 1;
} else {
lloc->last_column++;
}
}
}
#define YY_USER_ACTION update_yylloc(parser, yylloc, yytext);
%}
ID [^(){};\\[:space:]]+
STRING \"(\\.|[^"\\])*\"
HEX 0[xX][0-9a-fA-F]+
DEC -?[0-9]+
OCT 0[0-8]+
BIN 0b[0-1]+
INT {HEX}|{DEC}|{OCT}|{BIN}
HEXF [+-]?0[xX][0-9a-fA-F]+([pP][+-]?[0-9]+)
DECF [+-]?[0-9]+[.]([eE]?[+-]?[0-9]+)?[fF]?
FLOAT {HEXF}|{DECF}
%%
"#".* {/* skip line comments */}
"(" {return LPAREN;}
")" {return RPAREN;}
"{" {return LBRACE;}
"}" {return RBRACE;}
";" {return SEMICOLON;}
"\\" {return BACKSLASH;}
"\n" {return NL;}
{STRING} {
/* seems risky, I know, but letting the parser choose when to allocate a
* new string seems to help with syntax error cleanup */
yylval->str = yytext;
return STRING;
}
{INT} {
yylval->integer = strtoull(yytext, 0, 0);
return INT;
}
{FLOAT} {
yylval->floating = strtod(yytext, 0);
return FLOAT;
}
{ID} {
yylval->str = yytext;
return ID;
}
[^\n[:graph:]]+ {/* skip whitespace */}
. {
struct src_issue issue;
issue.level = SRC_ERROR;
issue.loc = src_loc(*yylloc);
issue.fctx.fbuf = parser->buf;
issue.fctx.fname = parser->fname;
src_issue(issue, "Unexpected token: %s", yytext);
parser->failed = true;
}
%%
|
