/* SPDX-License-Identifier: copyleft-next-0.3.1 */
/* Copyright 2023 Kim Kuparinen < kimi.h.kuparinen@gmail.com > */

%{

/* TODO: clean up this mess and I guess fix location tracking, it works for the
 * parser but each ast node should also get some location data
 * I'm trying something over in ast.c, but I'm not sure about it
 */

#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <assert.h>

#include <lyn/parser.h>
#include <lyn/ast.h>

%}

%locations

%define parse.trace
%define parse.error verbose
%define api.pure full
%define lr.type ielr

%lex-param {void *scanner} {struct parser *parser}
%parse-param {void *scanner} {struct parser* parser}

%union {
	struct lyn_value ast;
	char *str;
	long long integer;
	double floating;
};

%token <str> STRING
%token <str> ID
%token <integer> INT
%token <floating> FLOAT

%token LPAREN "("
%token RPAREN ")"
%token LBRACE "{"
%token RBRACE "}"
%token SEMICOLON ";"
%token BACKSLASH "\\"
%token NL "nl"

%nterm <ast> arg args
%nterm <ast> cmd cmds cmd_list

%{

/** Modifies the signature of yylex to fit our parser better. */
#define YY_DECL int yylex(YYSTYPE *yylval, YYLTYPE *yylloc, \
	                  void *yyscanner, struct parser *parser)

/**
 * Declare yylex.
 *
 * @param yylval Bison current value.
 * @param yylloc Bison location info.
 * @param yyscanner Flex scanner.
 * @param parser Current parser state.
 * @return \c 0 when succesful, \c 1 otherwise.
 * More info on yylex() can be found in the flex manual.
 */
YY_DECL;

/**
 * Convert bison location info to our own source location info.
 *
 * @param yylloc Bison location info.
 * @return Internal location info.
 */
static struct src_loc src_loc(YYLTYPE yylloc);

/**
 * Print parsing error.
 * Automatically called by bison.
 *
 * @param yylloc Location of error.
 * @param lexer Lexer.
 * @param parser Parser state.
 * @param msg Message to print.
 */
static void yyerror(YYLTYPE *yylloc, void *lexer,
		struct parser *parser, const char *msg);

%}

%start input;
%%

arg
	: "(" cmd_list ")" {$$ = $2; $$.kind = LYN_APPLY;}
	| "{" cmd_list "}" {$$ = $2; $$.kind = LYN_GROUP;}
	| ID {$$ = gen_id($1);}
	| STRING {$$ = gen_str($1);}
	| INT {$$ = gen_int($1);}
	| FLOAT {$$ = gen_float($1);}

cont
	: BACKSLASH NL

args
	: args cont arg {$$ = $1; vect_append(struct lyn_value, $$.args, &$3);}
	| args arg {$$ = $1; vect_append(struct lyn_value, $$.args, &$2);}
	| arg {$$ = gen_list(); vect_append(struct lyn_value, $$.args, &$1);}

sep
	: sep ";"
	| sep NL
	| ";"
	| NL

cmd
	: args {$$ = $1; $$.kind = LYN_CMD;}

cmds
	: cmds sep cmd {$$ = $1; vect_append(struct lyn_value, $$.args, &$3);}
	| cmd {$$ = gen_list(); vect_append(struct lyn_value, $$.args, &$1);}

cmd_list
	: cmds
	| cmds sep
	| sep cmds {$$ = $2;}
	| sep cmds sep {$$ = $2;}
	| {$$ = gen_list();}

input
	: cmd_list {$1.kind = LYN_GROUP; parser->tree = $1;}
	| error {parser->failed = true;}

%%

#include "gen_lexer.inc"

static struct src_loc src_loc(YYLTYPE yylloc)
{
	struct src_loc loc;
	loc.first_line = yylloc.first_line;
	loc.last_line = yylloc.last_line;
	loc.first_col = yylloc.first_column;
	loc.last_col = yylloc.last_column;
	return loc;
}

static void yyerror(YYLTYPE *yylloc, void *lexer,
		struct parser *parser, const char *msg)
{
	(void)lexer;

	struct src_issue issue;
	issue.level = SRC_ERROR;
	issue.loc = src_loc(*yylloc);
	issue.fctx.fbuf = parser->buf;
	issue.fctx.fname = parser->fname;
	src_issue(issue, msg);
}

struct parser *create_parser()
{
	return calloc(1, sizeof(struct parser));
}

void destroy_parser(struct parser *p)
{
	yylex_destroy(p->lexer);
	free(p);
}

void parse(struct parser *p, const char *fname, const char *buf)
{
	p->fname = fname;
	p->buf = buf;

	p->failed = false;

	yylex_init(&p->lexer);
	yy_scan_string(buf, p->lexer);
	yyparse(p->lexer, p);
}